Hébergeur de fichiers indépendant

2D o.dgibi

À propos

Type de fichier
Fichier DGIBI de 6 Ko (text/plain)
Confidentialité
Fichier public, envoyé le 21 avril 2017 à 17:53, depuis l'adresse IP 162.38.x.x (France)
Sécurité
Ne contient aucun Virus ou Malware connus - Dernière vérification: hier
Statistiques
La présente page de téléchargement a été vue 283 fois depuis l'envoi du fichier
Page de téléchargement

Aperçu du fichier


*2345678901234567890123456789012345678901234567890112345678901234567890

OPTI TRAC OPEN;

OPTI DIME 2 MODE PLAN DEFO ELEM TRI3;

***************************************
* PARAMETRISATION, DONNEES
***************************************

*angle en degre
AN = 0; 

*E base / E poulie
RPTYNG = 1;

*force
NO = 800; COMM para;

TA = 'TAN'   AN ;
CO= 'COS'   AN ;
SI= 'SIN'   AN ;

*profondeur trou
P=0.671429; COMM para;
*longueur base
L=1.5;
*hauteur base
H=0.2+P;
*rayon trou
R=0.02;  

*rayon tige
RP = R;
*hauteur tige
HP = 1;
*petit rayon poulie
R1 = 0.18;
*grand rayon poulie
R2 = 0.20;
*epaisseur poulie
EP = 0.06;

PI=3.1416;

*nombre de mailles
NB = 1;
*longueur de reference densite
LR = R2-R1;

***************************************
*TROU
***************************************

*Points
P1 = 0 0;
P2 = L. 0.;
P3 = L. H;
P4 =((R)+(L/2)) H;
P5 =((R)+(L/2)) (H-P);
P6 =(((-1)*(R))+(L/2)) (H-P);
P7 =(((-1)*(R))+(L/2)) H;
P8 = 0. H;


*Longueurs
L12=L;
L23=H;
L34=(0.5*L-R);
L45=P;
L56=2*R;
L67=P;
L78=(0.5*L-R);
L81=H;

*Densites
N12 = ENTI(NB*(L12/LR));
N23 = ENTI(NB*(L23/LR));
N34 = ENTI(NB*(L34/LR)); 
N45 = ENTI(NB*(L45/LR));
N56 = ENTI(NB*(L56/LR));
N67 = ENTI(NB*(L67/LR));
N78 = ENTI(NB*(L78/LR));
N81 = ENTI(NB*(L81/LR));


*Lignes
P1P2 = P1 D N12 P2;
P2P3 = P2 D N23 P3;
P3P4 = P3 D N34 P4;
P4P5 = P4 D N45 P5;
P5P6 = P5 D N56 P6;
P6P7 = P6 D N67 P7;
P7P8 = P7 D N78 P8;
P8P1 = P8 D N81 P1;

LT= P1P2 ET P2P3 ET P3P4 ET P4P5 ET P5P6 ET P6P7 ET P7P8 ET P8P1;

SURFB=SURF PLAN LT;
*TRAC QUAL SURFB;

***************************************
*POULIE
***************************************


*points
PP1 = ((-1)*(RP)) 0.;
PP2 = RP 0.; 
PP3 = PP2 PLUS (0 HP);
PP4 = R2 HP;
PP5 = PP4 PLUS (0 EP);
PP6 = R1 (HP+EP);
PP7 = PP6 PLUS (0 EP);
PP8 = R2 (HP+(2*EP));
PP9 = PP8 PLUS (0 EP);
PP10 = (-1)*R2 (HP+(3*EP));
PP11 = PP10 PLUS (0 ((-1)*EP));
PP12 = (-1)*R1 (HP+(2*EP));
PP13 = PP12 PLUS (0 ((-1)*EP));
PP14 = (-1)*R2 (HP+EP);
PP15 = (-1)*R2 (HP+(0*EP));
PP16 = ((-1)*(RP)) HP;

*densite de noeud
L12=2*RP;
L23=HP;
L34=R2-RP;
L45=EP;
L56=R2-R1;
L67=EP;
L78=R2-R1;
L89=EP;
L910=2*R2;
L1011=EP;
L1112=R2-R1;
L1213=EP;
L1314=R2-R1;
L1415=EP;
L1516=R2-RP;
L161=HP;

N12 = ENTI(NB*(L12/LR));
N23 = ENTI(NB*(L23/LR));
N34 = ENTI(NB*(L34/LR)); 
N45 = ENTI(NB*(L45/LR));
N56 = ENTI(NB*(L56/LR));
N67 = ENTI(NB*(L67/LR));
N78 = ENTI(NB*(L78/LR));
N89 = ENTI(NB*(L89/LR));
N910 = ENTI(NB*(L910/LR));
N1011 = ENTI(NB*(L1011/LR));
N1112 = ENTI(NB*(L1112/LR));
N1213 = ENTI(NB*(L1213/LR));
N1314 = ENTI(NB*(L1314/LR));
N1415 = ENTI(NB*(L1415/LR));
N1516 = ENTI(NB*(L1516/LR));
N161 = ENTI(NB*(L161/LR));


*lignes
PP1PP2 = PP1 D N12 PP2;
PP2PP3 = PP2 D N23 PP3;
PP3PP4 = PP3 D N34 PP4;
PP4PP5 = PP4 D N45 PP5;
PP5PP6 = PP5 D N56 PP6;
PP6PP7 = PP6 D N45 PP7;
PP7PP8 = PP7 D N56 PP8;
PP8PP9 = PP8 D N45 PP9;
PP9PP10 = PP9 D N910 PP10;
PP10PP11 = PP10 D N1011 PP11;
PP11PP12 = PP11 D N1112 PP12;
PP12PP13 = PP12 D N1213 PP13;
PP13PP14= PP13 D N1314 PP14;
PP14PP15 = PP14 D N1415 PP15;
PP15PP16 = PP15 D N1516 PP16;
PP16PP1 = PP16 D N161 PP1;

LTOT1 = PP1PP2 ET PP2PP3 ET PP3PP4 ET PP4PP5 ET PP5PP6 ET PP6PP7;
LTOT2 = PP7PP8 ET PP8PP9 ET PP9PP10 ET PP10PP11 ET PP11PP12;
LTOT3 = PP12PP13 ET PP13PP14 ET PP14PP15 ET PP15PP16 ET PP16PP1;
LTOT = LTOT1 ET LTOT2 ET LTOT3;

*surface
SURFP = SURF PLAN LTOT;
SURFP = SURFP PLUS ((L/2) (H-P));
*TRAC QUAL SURFP;

STOT = SURFB ET SURFP;
ELIM 1E-2 STOT;
*TRAC QUAL STOT; 
************************************************
* modele et materiaux
************************************************
*la poulie
YO2   = 200E+9;
PO2   = 0.3;

*la base
YO1   = YO2*RPTYNG;
PO1   = 0.3;


MOD1 = MODE SURFB MECANIQUE ELASTIQUE ISOTROPE ;
MAT1 = MATE MOD1 YOUN YO2 NU PO1;
MOD2 = MODE SURFP MECANIQUE ELASTIQUE ISOTROPE ;
MAT2 = MATE MOD2 YOUN YO1 NU PO2;
MODT = MOD1 ET MOD2; 
MATT = MAT1 ET MAT2;

************************************************
* conditions aux limites
************************************************

*TRAC QUAL STOT;

CLT = BLOQ DEPLA ROTA P1P2;
*CL2 = BLOQ DEPLA ROTA P8P1;
*CL3 = BLOQ DEPLA ROTA P2P3;
*CLT = CL1 ET CL2 ET CL3;

************************************************
* chargement
************************************************
*points de chargement
PP10F = PP12 PLUS ((L/2) (H-P));
PP11F = PP13 PLUS ((L/2) (H-P));

GEOT = SURFP POIN DROIT PP10F PP11F 0.0001;

*TRAC QUAL (GEOT COUL ROUG ET STOT);

PX = NO*CO;
PY = NO*SI*(-1);
FOR1 = FORCE FX PX GEOT;
FOR2 = FORCE FY PY GEOT;
FORT = FOR1 ET FOR2;
VEC1 = VECT FORT FX FY ROUG;
*TRAC VEC1 STOT;

************************************************
* matrice de rigidite
************************************************

RIG1 = RIGI MODT MATT;
RIGT = RIG1 ET CLT;

************************************************
* resolution
************************************************

DEPLT = RESO RIGT FORT;

************************************************
* postraitement
************************************************

* trace maillage initial et deforme
* ---------------------------------

DEF0 = DEFO STOT DEPLT 0. BLAN;
DEF1 = DEFO STOT DEPLT 1. BLEU;

*TRAC (DEF0 ET DEF1);

* posttraitement
* --------------

SS   = SIGM MODT MATT DEPLT;

SSYY = EXCO SMYY SS;
*TRAC DEF1 MODT SSYY;

SSXX = EXCO SMXX SS;
*TRAC DEF1 MODT SSXX;

SSXY = EXCO SMXY SS;
*TRAC DEF1 MODT SSXY;

SSVM = VMIS MODT SS;
*TRAC DEF1 MODT SSVM;

*calcul du deplacement max sur X 
PA = ((L/2)-R2) ((3*EP)+HP+2);
PTA  = STOT POIN PROC PA ;
DAX     = EXTR DEPLT UX PTA ;

*calcul du deplacement max de A sur Y 
PA = ((L/2)-R2) ((3*EP)+HP+2);
PTA  = STOT POIN PROC PA ;
DAY     = EXTR DEPLT UY PTA ;

*calcul du deplacement max de A sur Y 
PB = ((L/2)+R2) ((3*EP)+HP+2);
PTB  = STOT POIN PROC PB ;
DBY    = EXTR DEPLT UY PTB ;

ATAN = 'ATG' (180*(DAY-DBY)/(PI*2*R2));
MXSSVM=(MAXI SSVM);

MESS '----> DX ='  ATAN;
MESS '----> DAX =' DAX;
MESS '----> VMIS MAX SUR VOLT =' MXSSVM;

fin;



Partager le fichier


Télécharger 2D_o.dgibi


Télécharger 2D_o.dgibi